Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Поиск точного числа в интервале
 
#1
24.04.2024 10:57:45
Добрый день!
Подскажите, пожалуйста, как можно решить данную задачу.
Есть значения вертикальной глубины МD: 20 40 60... как сделать чтобы при вводе значения МD (например 53 или 1537) автоматически ниже появлялось соответствующее ему конкретное абсолютное значение.

Поискав на форуме информацию, ближайшее к теме, что нашел это функции ИНДЕКС и ПОИСКПОЗ, но как сделать, чтобы можно было получать абсолютное значение на любое введенное МД?
 
 
 
#2
24.04.2024 11:02:41
при 53 какое значение должно быть?
У ПОИСКПОЗ 0 заменить на 1 может подойдет.
 
 
 
#3
24.04.2024 11:03:34
Raneli,
может так:
Код
=ИНДЕКС(Таблица1[[#Все];[Абсолютная глубина]]; ПОИСКПОЗ(N4;Таблица1[[#Все];[MD]];1))
Изменено: evgeniygeo - 24.04.2024 11:04:33
 
 
 
#4
24.04.2024 11:07:05
Raneli,
Здравствуйте.
Так у Вас в файле вроде и так всё правильно показывает. В чём проблема-то?
 
 
 
#5
24.04.2024 11:15:14
При 53 должно быть -38,1

Проблема в том что, 0 или 1 не подойдет, так как значение будет далеко от истинного, к примеру при использовании приблизительного значения получается:
Что при МД=40 абсолютное значение будет равно понятно -48,64, но и при МД=53 тоже -48,64, а как видно выше разница  значительная и составляет 10,5
 
 
 
#6
24.04.2024 11:25:19
Цитата
написал:
При 53 должно быть -38,1
объясните как получили -38,1.
 
 
 
#7
24.04.2024 11:29:38
38,1 как высчитали? у меня вышло 35,65
Код
=ПРЕДСКАЗ(N4;СМЕЩ(ИНДЕКС($F$2:$F$32;ПОИСКПОЗ(N4;$B$2:$B$32;1));;;2;1);СМЕЩ(ИНДЕКС($B$2:$B$32;ПОИСКПОЗ(N4;$B$2:$B$32;1));;;2;1))
Изменено: V - 24.04.2024 11:34:40
 
 
 
#8
24.04.2024 11:36:11
Извиняюсь забыл передвинуть ячейки в формуле -35,6 получается
т.к. в  20 метрах МД между 40 и 60  получается 19,99 м, но это разница с глубиной значительно изменяется с учетом кривизны скважины

Ниже прикладываю файл, как получил значение
 
 
 
#9
24.04.2024 11:47:08
Вы ж получили значение. Вам это одной формулой надо?
Код
=(ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1)+1;6)-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);6))/((ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1)+1;2)-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);2)))*(N4-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);2))+ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);6)
Изменено: МатросНаЗебре - 24.04.2024 11:50:24
 
 
 
#10
24.04.2024 11:49:10
Укажите какая у вас версия эксель.
 
 
 
#11
24.04.2024 11:54:23
Цитата
написал:
Вы ж получили значение. Вам это одной формулой надо?
Да это на примере, на самом деле выборка значений большая, а количество скважин еще больше, а таких значений бывает нужно много и часто:)
Хочется ускорить рабочий процесс.
 
 
 
#12
24.04.2024 11:57:00
Цитата
написал:
Укажите какая у вас версия эксель.
Microsoft Office стандартный 2016
 
 
 
#13
24.04.2024 12:02:50
Код
=(ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1)+1;6)-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);6))/((ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1)+1;2)-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);2)))*(N4-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);2))+ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);6)
 
 
 
#14
24.04.2024 12:03:14
Цитата
написал:
Вы ж получили значение. Вам это одной формулой надо?Код=(ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1)+1;6)-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);6))/((ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1)+1;2)-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);2)))*(N4-ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);2))+ИНДЕКС(A1:K97; ПОИСКПОЗ(N4;B1:B97;1);6)


Изменено: МатросНаЗебре  - 24.04.2024 11:50:24
Спасибо, гениальное решение:)
 
 
 
#15
24.04.2024 12:04:55
если добавить столбец то формула чуть проще
 
 
 
#16
24.04.2024 12:17:44
Цитата
написал:
если добавить столбец то формула чуть проще

Прикрепленные файлы
Пример.xlsx  (31.57 КБ)
Спасибо!
 
 
 
#17
24.04.2024 15:22:49
еще возможность
=ПРЕДСКАЗ(N4;ИНДЕКС(Таблица1[Абсолютная глубина];Ч(ПОИСКПОЗ(N4;Таблица1[MD])+{0:1}));ИНДЕКС(Таблица1[MD];Ч(ПОИСКПОЗ(N4;Таблица1[MD])+{0:1})))
 
 
 
Страницы: 1
Наверх