Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Проверить содержит ли строка определённые символы, Формула проверка надежности пароля
 
#1
25.04.2024 10:55:06
Здравствуйте! Помогите, пожалуйста, решить такую задачу.
На школьной компьютерной конференции, посвящённой безопасному использованию вычислительной техники, выступил ученик пятого класса Андрей Иванов. В своем выступлении о важности сложного пароля в современном цифровом пространстве он упомянул, что уже обладает знаниями, позволяющими взломать любой пароль, состоящий только из букв и цифр. Сложным и безопасным паролем можно считать пароль, содержащий помимо букв и цифр другие символы – спецсимволы.
С помощью табличного процессора определите, является ли ваш пароль безопасным к взлому Андрея или же защищает ваш компьютер только от родителей и кота Василия. Если пароль безопасный, то он выделяется зелёным цветом, если же пароль «слабый», то он выделяется красным цветом.
В приложении как должен выглядеть и символы.
С условным форматированием все понятно, написать формулу не могу.
 
 
 
#2
25.04.2024 11:08:10
Допустим символы находятся в диапазоне A1:A30, тогда формулу вставляем в диапазон B1:B30
Код
=НЕ(ЕОШ(НАЙТИ(A1;$C$4)))
Итоговая формула, возвращающая, содержит ли строка символы, будет:
Код
=ИЛИ($B$1:B$30)
Вариант названия темы:
Формула, показывающая, содержит ли строка/пароль определённые символы
 
 
 
#3
25.04.2024 11:14:08
Без вспомогательного столбца. По крайней мере, без вспомогательного столбца не на этапе составления формулы )
Код
=ИЛИ(
НЕ(ЕОШ(НАЙТИ("!";$C$4)));
НЕ(ЕОШ(НАЙТИ("""";$C$4)));
НЕ(ЕОШ(НАЙТИ("#";$C$4)));
НЕ(ЕОШ(НАЙТИ("$";$C$4)));
НЕ(ЕОШ(НАЙТИ("%";$C$4)));
НЕ(ЕОШ(НАЙТИ("&";$C$4)));
НЕ(ЕОШ(НАЙТИ("'";$C$4)));
НЕ(ЕОШ(НАЙТИ("(";$C$4)));
НЕ(ЕОШ(НАЙТИ(")";$C$4)));
НЕ(ЕОШ(НАЙТИ("*";$C$4)));
НЕ(ЕОШ(НАЙТИ("+";$C$4)));
НЕ(ЕОШ(НАЙТИ(",";$C$4)));
НЕ(ЕОШ(НАЙТИ("-";$C$4)));
НЕ(ЕОШ(НАЙТИ(".";$C$4)));
НЕ(ЕОШ(НАЙТИ("/";$C$4)));
НЕ(ЕОШ(НАЙТИ(":";$C$4)));
НЕ(ЕОШ(НАЙТИ(";";$C$4)));
НЕ(ЕОШ(НАЙТИ("<";$C$4)));
НЕ(ЕОШ(НАЙТИ("=";$C$4)));
НЕ(ЕОШ(НАЙТИ(">";$C$4)));
НЕ(ЕОШ(НАЙТИ("?";$C$4)));
НЕ(ЕОШ(НАЙТИ("@";$C$4)));
НЕ(ЕОШ(НАЙТИ("[";$C$4)));
НЕ(ЕОШ(НАЙТИ("\";$C$4)));
НЕ(ЕОШ(НАЙТИ("]";$C$4)));
НЕ(ЕОШ(НАЙТИ("^";$C$4)));
НЕ(ЕОШ(НАЙТИ("{";$C$4)));
НЕ(ЕОШ(НАЙТИ("|";$C$4)));
НЕ(ЕОШ(НАЙТИ("}";$C$4)));
НЕ(ЕОШ(НАЙТИ("~";$C$4)));
)
 
 
 
#4
25.04.2024 11:26:19
Цитата
alisa-gb написал:
обладает знаниями, позволяющими взломать любой пароль
Правила форма:
Цитата
3. Запрещено
...
Все темы, прямо или косвенно касающиеся взлома любых паролей будут удаляться без предупреждения.
...
:)  ;)
Согласие есть продукт при полном непротивлении сторон
 
 
 
#5
25.04.2024 11:31:36
Всё норм. Формула требуется для противодействия злобному гению(ученику пятого класса Андрею Иванову), обладающего знаниями, позволяющими взломать пароль  :D  
Изменено: МатросНаЗебре - 25.04.2024 11:32:21
 
 
 
#6
25.04.2024 11:43:31
Цитата
написал:
3. Запрещено...Все темы, прямо или косвенно касающиеся взлома любых паролей будут удаляться без предупреждения.
Извините, не подумала. На самом деле, это олимпиадное задание)
Изменено: alisa-gb - 25.04.2024 12:51:05
 
 
 
#7
25.04.2024 12:01:53
Цитата
alisa-gb написал:
В своем выступлении о важности сложного пароля в современном цифровом пространстве он упомянул, что уже обладает знаниями, позволяющими взломать любой пароль, состоящий только из букв и цифр. Сложным и безопасным паролем можно считать пароль, содержащий помимо букв и цифр другие символы – спецсимволы.
Дааа, а потом такие гении приходят в реальный мир и ничего не могу сделать.

Цитата
alisa-gb написал:
Сложным и безопасным паролем можно считать пароль, содержащий помимо букв и цифр другие символы – спецсимволы.
Интересно , сложен ли пароль: _1Ab
все соблюдено.
В современном мире 2FA  защищает.

А по вопросу, Все просто . Если нужно иметь спец символы , цифры и буквы разного регистра, то достаточно проверить вхождение символа в одну из групп и просуммировать - жолжно быть в сумме 4, массивка исключающая кириллицу
=SUM(--ISNUMBER(MATCH({1\2\3\4};IFERROR(LOOKUP(CODE(MID(F26;ROW(1:99);1));{0;48;58;65;91;97;123;192};{1;2;1;3;1;4;1;0});0);)))=4

при этом должна быть еще длина пароля, но об этом в пятом классе еще не проходили.
По вопросам из тем форума, личку не читаю.
 
 
 
#8
25.04.2024 12:10:23
Здравствуйте
вариант поиска этих
Цитата
Прикрепленные файлы:    10_2_Символы.txt (88 Б)
символов:
=СУММПРОИЗВ(--ЕЧЁТН(ПОИСКПОЗ(КОДСИМВ(ПСТР(C4;СТРОКА(A$1:ИНДЕКС(A:A;ДЛСТР(C4)));1));{0:33:48:58:65:91:97:123:127})))
Изменено: Павел \Ʌ/ - 25.04.2024 12:10:59
 
 
 
#9
25.04.2024 13:05:59
Цитата
написал:
=СУММПРОИЗВ(--ЕЧЁТН(ПОИСКПОЗ(КОДСИМВ(ПСТР(C4;СТРОКА(A$1:ИНДЕКС(A:A;ДЛСТР(C4)));1));{0:33:48:58:65:91:97:123:127})))
Спасибо за ответ, но находит количество символов в пароле. В задаче сказано: "Сложным и безопасным паролем можно считать пароль, содержащий помимо букв и цифр другие символы – спецсимволы." А при наличии какого количества считать пароль надежным?  Если пароль содержит только 1 или несколько специальных символов, то он надежный?
 
 
 
#10
25.04.2024 13:21:40
Цитата
написал:
=НЕ(ЕОШ(НАЙТИ(A1;$C$4)))
Спасибо за ответ! Находит специальные символы. Можно посчитать их количество. Применила в файле. Может задача неудачно сформулирована  как определить надежность пароля.  
 
 
 
#11
25.04.2024 13:53:05
Цитата
alisa-gb написал:
как определить надежность пароля.  
#7
Дополнительно проверить длинну  - не проблема.
По вопросам из тем форума, личку не читаю.
 
 
 
#12
25.04.2024 14:10:01
потестируйте такой вариант )
{ }
=ЕСЛИОШИБКА(ВЫБОР(СУММ(EXP(LN((ЧАСТОТА(КОДСИМВ(ПСТР(C4;СТРОКА(A$1:ИНДЕКС(A:A;ДЛСТР(C4)));1));{32:47:57:64:90:96:122:126})>0)*{-1:1:1:1:1:1:1:1:-1}+{1:1:1:1:1:1:1:1:1}))-{1:1:1:1:1:1:1:1:1});"хреновый";"очень плохой";"плохой";"удовлетворительный";"хороший";"очень хороший";"отличный");"неприемлимые символы")
 
 
 
#13
25.04.2024 14:36:47
Цитата
написал:
=ЕСЛИОШИБКА(ВЫБОР(СУММ(EXP(LN((ЧАСТОТА(КОДСИМВ(ПСТР(C4;СТРОКА(A$1:ИНДЕКС(A:A;ДЛСТР(C4)));1));{32:47:57:64:90:96:122:126})>0)*{-1:1:1:1:1:1:1:1:-1}+{1:1:1:1:1:1:1:1:1}))-{1:1:1:1:1:1:1:1:1});"хреновый";"очень плохой";"плохой";"удовлетворительный";"хороший";"очень хороший";"отличный");"неприемлимые символы")
Огромное спасибо! В любом случае работает!!!
Школьнику такое точно не написать!
 
 
 
#14
25.04.2024 15:14:51
alisa-gb, здравствуйте!
Цитата
alisa-gb: В своем выступлении о важности сложного пароля в современном цифровом пространстве он упомянул, что уже обладает знаниями, позволяющими взломать любой пароль, состоящий только из букв и цифр.
он, конечно, глубоко заблуждается.
Наличие спецсимволов, всего лишь, расширяет библиотеку [символов] для создания строки. Гораздо важнее длина пароля и его непредсказуемость, т.к. "Hello", "Password", многие другие и их вариации — "пробиваются" в 1ю очередь (даже сайты есть с такими подборками ненадёжных паролей).
Изменено: Jack Famous - 25.04.2024 15:15:07
Во всех делах очень полезно периодически ставить знак вопроса к тому, что вы с давних пор считали не требующим доказательств (Бертран Рассел) ►Благодарности сюда◄
 
 
 
Страницы: 1
Наверх