Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1 2 След.
RSS
Подсчёт количества обучаючихся на оценки 4 и 5 с помощью формул, Подсчёт количества обучаючихся на оценки 4 и 5 с помощью формул
 
#1
03.05.2024 07:44:19
Здравствуйте, что то ничего в голову не приходит.
Как сделать подсчёт количества обучаючихся на оценки 4 и 5 с помощью формул в ячейки C32
 
 
 
#2
03.05.2024 07:47:33
счётесли?
 
 
 
#3
03.05.2024 07:48:53
Наличие н/а по предмету играет какую-то роль?
Согласие есть продукт при полном непротивлении сторон
 
 
 
#4
03.05.2024 07:51:56
=СЧЁТЕСЛИМН(C1:C29;">=4";D1:D29;">=4";E1:E29;">=4";F1:F29;">=4";G1:G29;">=4";H1:H29;">=4";I1:I29;">=4";J1:J29;">=4";K1:K29;">=4")
Вот так пробовал, но хочется сократить формулу
 
 
 
#5
03.05.2024 07:52:44
н/а нужно для дальнейшего рассчёта неуспевающих

Цитата
написал:
Наличие н/а по предмету играет какую-то роль?
 
 
 
#6
03.05.2024 07:58:25
Вам нужно посчитать 'отличников' по каждому предмету отдельно? Или сколько всего учеников учатся на 4 и 5?
Согласие есть продукт при полном непротивлении сторон
 
 
 
#7
03.05.2024 08:04:01
Цитата
написал:
Вам нужно посчитать 'отличников' по каждому предмету отдельно? Или сколько всего учеников учатся на 4 и 5?
"Сколько всего учеников учатся на 4 и 5?"
 
 
 
#8
03.05.2024 08:09:38
С доп.столбцом
Согласие есть продукт при полном непротивлении сторон
 
 
 
#9
03.05.2024 08:12:48
Нужно без доп столбца  
 
 
 
#10
03.05.2024 08:18:36
Так?
=СЧЁТЕСЛИ(C3:C29;">3")
 
 
 
#11
03.05.2024 08:26:04
Цитата
написал:
Так?=СЧЁТЕСЛИ(C3:C29;">3")
Нет, так считается только оценки по прикладной электроники, там ещё другие дисциплины
 
 
 
#12
03.05.2024 08:30:57
Тогда так:
=СУММПРОИЗВ((C3:K29=5)+(C3:K29=4))
 
 
 
#13
03.05.2024 08:38:36
170 получается, там всего их 27...
 
 
 
#14
03.05.2024 08:42:32
Здравствуйте. Вариант, массив. н/а = 2
Код
=СУММ(--(МУМНОЖ(--(ЕСЛИ($C$3:$K$29="н/а";2;$C$3:$K$29)>3);ТРАНСП(СТОЛБЕЦ($C$2:$K$2))^0)=ЧИСЛСТОЛБ($C$2:$K$2)))
 
 
 
#15
03.05.2024 08:44:39
Цитата
написал:
Здравствуйте. Вариант, массив. н/а = 2
Слишком сложная формула, не смогу объяснить её,а это обязательно нужно.
Есть ли другой вариант?
Можете сделать подсчёт количества неуспеваемых (если есть хотя бы одна двойка или н/а)?
 
 
 
#16
03.05.2024 08:56:58
Цитата
flyymann написал:
Слишком сложная формула, не смогу объяснить её,
Вот попроще (вроде)
=СУММПРОИЗВ((C3:C29>3)*(D3:D29>3)*(E3:E29>3)*(F3:F29>3)*(G3:G29>3)*(H3:H29>3)*(I3:I29>3)*(J3:J29>3)*(K3:K29>3))
 
 
 
#17
03.05.2024 08:57:01
А чем Вам ваша же формула не угодила? Из сообщения #4?
Согласие есть продукт при полном непротивлении сторон
 
 
 
#18
03.05.2024 09:04:28
Цитата
написал:
А чем Вам ваша же формула не угодила? Из сообщения #4?
Она мне нравится, но я её не понимаю, а мне это обязательно нужно. Не могли бы вы расписать что там да как работает?
 
 
 
#19
03.05.2024 09:09:19
Для Excel 365:
=СУММ(--BYROW(Ч(+C3:K29);LAMBDA(x;И(x>3))))
или можно и так:
=СУММ(--BYROW(Ч(+C3:K29)>3;LAMBDA(x;И(x))))
Изменено: Бахтиёр - 03.05.2024 09:36:34
 
 
 
#20
03.05.2024 10:57:05
Цитата
flyymann написал:
я её не понимаю
Excel СЧЕТЕСЛИМН
Согласие есть продукт при полном непротивлении сторон
 
 
 
#21
03.05.2024 13:58:34
Неужели больше вариантов нет, без новомодных функций и доп столбцов, кроме варианта Serg091. Вот UDF легко написать, а формулу видимо сложно.
 
 
 
#22
03.05.2024 14:32:01
Цитата
Евгений Смирнов написал:
Неужели больше вариантов нет,
ну странно что COUNTIFS так не любим
ну можно чуть сократить
=COUNTIFS(C1:C29;">3";D1:D29;">3";E1:E29;">3";F1:F29;">3";G1:G29;">3";H1:H29;">3";I1:I29;">3";J1:J29;">3";K1:K29;">3")
или
=SUM(--(MMULT(--TEXT(C3:K29;"[>3]1;\0;\0;\0");TRANSPOSE(COLUMN(C3:K29))^0)=COLUMNS(C3:K29)))
По вопросам из тем форума, личку не читаю.
 
 
 
#23
03.05.2024 15:46:46
Цитата
Евгений Смирнов:    Неужели больше вариантов нет, без новомодных функций
С какой целью интересуетесь? )
=СУММ((ПРОМЕЖУТОЧНЫЕ.ИТОГИ(5;СМЕЩ(C2:K2;A3:A29;))>3)*(ПРОМЕЖУТОЧНЫЕ.ИТОГИ(2;СМЕЩ(C2:K2;A3:A29;))=СЧЁТЗ(C2:K2)))
но волатильна и...  "объяснять не хочется как работает"  )
 
 
 
#24
03.05.2024 16:05:38
Павел \Ʌ/, СМЕЩЬ - летучая , а вот OFFSET - волатильная   :D
По вопросам из тем форума, личку не читаю.
 
 
 
#25
03.05.2024 23:02:32
Павел \Ʌ/
Цитата
С какой целью интересуетесь? )
Хочу сам немного научиться писать формулы, пока плохо получается, поэтому в некоторых темах пытаюсь разобраться как  работает формула ну и желательно смотреть какие могут быть еще варианты.
 
 
 
#26
04.05.2024 07:21:20
Цитата
Евгений Смирнов написал:
без новомодных функций
к радости/несчастью эти функции убивают изюминку создания формул , но делают возможным то что ранее не возможно было сделать, не только короче, но и в целом. При этом, добавляя скорость вычислений , конечно новшества только в +, но как же коряво выглядит смесь переведенных и не переведенных.
По вопросам из тем форума, личку не читаю.
 
 
 
#27
04.05.2024 10:03:20
Еще массивный вариант
Код
=СУММ(--(МУМНОЖ((C3:K29>3)*ЕЧИСЛО(C3:K29);ТРАНСП(СТОЛБЕЦ(C3:K29)^0))=9))

и обычный

Код
=СУММ(--(МУМНОЖ((C3:K29>3)*ЕЧИСЛО(C3:K29);{1:1:1:1:1:1:1:1:1})=9))
Алексей М.
 
 
 
#28
04.05.2024 13:14:06
АlехМ Оказывается можно еще немного изменить формулу, но видимо без  МУМНОЖ красиво не получится. Я пытался через векторную форму ИНДЕКС, но ничего у меня не получилось. По другому написал, но некрасиво и длинно.
Изменено: Евгений Смирнов - 04.05.2024 13:16:17
 
 
 
#29
04.05.2024 13:31:20
СЧЁТЕСЛИ вполне считает всё
Изменено: Александр А - 04.05.2024 20:04:50
 
 
 
#30
04.05.2024 17:08:35
Цитата
АlехМ:  =СУММ(--(МУМНОЖ((C3:K29>3)*ЕЧИСЛО(C3:K29);{1:1:1:1:1:1:1:1:1})=9))
еще подожмём  )
=СУММ(--(МУМНОЖ(--ЕЧИСЛО(1/(C3:K29-3>0));{1:1:1:1:1:1:1:1:1})=9))
 
 
 
Страницы: 1 2 След.
Наверх