Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Если ячейка содержит ТЕКСТ1,2,3, то значение равно N,Если ячейка содержит ТЕКСТ 4,5,6, то значение равно M и так много условий
 
#1
08.05.2018 00:53:32
Здравствуйте!Подскажите одну волшебную формулу, которая бы могла следующее:
Если ячейка содержит Текст1,2,3,4..., то значение 2,9, если  ячейка содержит Текст5,6,7..., то значение 2,8,  если  ячейка содержит Текст8,9,10...., то значение 2,7.
Сейчас пользуюсь вот такой формулой, но мне приходиться считать разные коэф, зависящие от разных ТЕКСТов в диапазоне, в разных столбиках, и потом через максимум сводить все в один столбец
=ЕСЛИ(ИЛИ(ЕЧИСЛО(ПОИСК(" Lieblingsstueck ";B15:B473));(ЕЧИСЛО(ПОИСК(" PENNY BLACK ";B15:B473)));(ЕЧИСЛО(ПОИСК(" Marc Aurel ";B15:B473))));2,7;0)

=ЕСЛИ(ИЛИ(ЕЧИСЛО(ПОИСК(" Rofa ";B15:B473));(ЕЧИСЛО(ПОИСК(" Rabe ";B15:B473)));(ЕЧИСЛО(ПОИСК(" Bluebery ";B15:B473)));(ЕЧИСЛО(ПОИСК(" Lebek ";B15:B473)));(ЕЧИСЛО(ПОИСК(" Steilmann ";B15:B473))));3;0)

Возможна ли одна формула?
Изменено: jenifer.06 - 08.05.2018 23:12:40 (загрузка примера)
 
 
 
#2
08.05.2018 06:08:06
без примера напрашивается ВПР
Лень двигатель прогресса, доказано!!!
 
 
 
#3
08.05.2018 06:21:22
jenifer.06, плохо, что нет файла с образцами исходного текста.
Вот такое набросал (см.вложение), попробуйте разобраться. Подробности в этой статье.
Pravé bohatství se skrývá uvnitř
 
 
 
#4
08.05.2018 07:51:58
jenifer.06, и правда пример в студию. ибо не понятно что вы хотитет особенно B15:B473 в поиск. Если у вам надо в найти коэффициент при наличии определенного слова в столбце, то не понятно что делать если есть несколько вхождений.
Для единичной, можно так

=INDEX({2,9;2,9;2,9;2,9;2,8;2,8;2,8;2,7;2,7;2,7};MATCH(1=1;ISNUMBER(SEARCH({" Текст1 ";" Текст2 ";" Текст3 ";" Текст4 ";" Текст5 ";" Текст6 ";" Текст7 ";" Текст8 ";" Текст9 ";" Текст10 "};B15));0))
=LOOKUP(2;1/ISNUMBER(SEARCH({" Текст1 ";" Текст2 ";" Текст3 ";" Текст4 ";" Текст5 ";" Текст6 ";" Текст7 ";" Текст8 ";" Текст9 ";" Текст10 "};B15));{2,9;2,9;2,9;2,9;2,8;2,8;2,8;2,7;2,7;2,7})
или так
=LOOKUP(MATCH(1=1;ISNUMBER(SEARCH({" Текст1 ";" Текст2 ";" Текст3 ";" Текст4 ";" Текст5 ";" Текст6 ";" Текст7 ";" Текст8 ";" Текст9 ";" Текст10 "};B15)));{1;5;8};{2,9;2,8;2,7})
=LOOKUP(LOOKUP(2;1/ISNUMBER(SEARCH({" Текст1 ";" Текст2 ";" Текст3 ";" Текст4 ";" Текст5 ";" Текст6 ";" Текст7 ";" Текст8 ";" Текст9 ";" Текст10 "};B15));ROW(1:10));{1;5;8};{2,9;2,8;2,7})
Изменено: БМВ - 09.05.2018 01:41:41
По вопросам из тем форума, личку не читаю.
 
 
 
#5
08.05.2018 23:14:43
Цитата
Сергей написал:
без примера напрашивается ВПР
О ВПР тоже знаю, и даже пробовала ей воспользоваться, но что-то не могу сообразить как ей пользоваться - подскажите! пример прикрепила
Изменено: jenifer.06 - 08.05.2018 23:15:11
 
 
 
#6
08.05.2018 23:19:48
Цитата
БМВ написал:
B15:B473 в поиск
это диапазон поиска, пример прикрепила, мне нужна одна формула, чтобы сразу получалось как в столбце с названием максимум, т.е. я сначала таким "макаром" при содержании определенных Текстов, ищу коэффициент(2,9   2,7  2,5   3   3,33 и т.д.) , а потом эти коэффициенты сливаю в один столбик, что бы пользоваться этим столбиком
 
 
 
#7
08.05.2018 23:22:46
Пример прикрепляю
 
 
 
#8
09.05.2018 00:18:31
jenifer.06, если изначально составить таблицу соответствий "бренд - коэффициент", то всё решается банальной массивкой: =МАКС(ЕСЛИОШИБКА(ПОИСК($O$3:$O$38;B2)^0*$P$3:$P$38;0))
Соблюдение правил форума не освобождает от модераторского произвола
 
 
 
#9
09.05.2018 01:35:01
:-)
=LOOKUP(MATCH(1=1;ISNUMBER(SEARCH({" Betty&Co ";" Monari ";" Brax ";" Frankwalder ";" LeComte ";" Le Comte ";" Passigatti ";" Roeckl ";" Gardeur ";" Otto Kessler ";" More&More ";" Biba ";" Seindensticker ";" Passport ";" MAC ";" Peruzzi ";" CLAUDIA STRATER ";" OTTO KERN ";" TUZZI ";" Fraas ";" Bianca ";" Lieblingsstueck ";" PENNY BLACK ";" Marc Aurel ";" Rofa ";" Rabe ";" Bluebery ";" Lebek ";" Steilmann ";" Bulmer ";" Basler ";" Sonia ";" HIGH ";" Lerock ";" Gerard Darel ";" Valentino ";" Bauer "};B2));0);{1;16;22;25;30;31};{2,9;2,8;2,7;3;2,5;3,33})

Но соглашусь с предыдущм оратором, сложности создаем сами. Нужно просто данные представить в удобном виде.
Ну и как предпологал, B15:B473 в ПОИСК(" Lieblingsstueck ";B15:B473));  совершенно ненужно, там должно быть B15 .
Изменено: БМВ - 09.05.2018 01:40:01
По вопросам из тем форума, личку не читаю.
 
 
 
Страницы: 1
Читают тему
Наверх